#!/bin/csh -f
#
# CUSTOMIZE utility
#
# To use this utility, make a directory containing the contents you want
# customized. Then, make a shell script in that directory called
# "customize.sh" that installs those files. Then, cd to that directory and
# run the following command to write onto a floppy disk
#
# tar cf /dev/fd0 *
#

onintr cleanup

echo -n "Would you like to install a customization floppy? [n] "
set confirm = $<
if (x"$confirm" !~ x[yY]*) then
    echo ' '
    echo 'Ok, using only standard DataReactor [tm] Core installation'
    echo ' '
    exit 0
endif

while (1)
    echo 'Insert the customization disk into the floppy drive'
    echo 'Press enter to continue'
    set dummy = $<
    mkdir /tmp/CUSTOMIZE.$$
    cd /tmp/CUSTOMIZE.$$
    tar xf /dev/fd0
    (chmod +x ./customize.sh && ./customize.sh) || echo Customization failed
    \rm -rf /tmp/CUSTOMIZE.$$
    echo ' '
    echo -n "Would you like to install another customization floppy? [n] "
    set confirm = $<
    if (x"$confirm" !~ x[yY]*) then
        echo ' '
	echo 'Customization completed'
	echo ' '
	exit 0
    endif
end

cleanup:
\rm -rf /tmp/CUSTOMIZE.$$